{
  description = "Common setup for many projects that use a variety of languages.";

  inputs = {
    nixpkgs.url = "https://flakehub.com/f/NixOS/nixpkgs/*.tar.gz";

    nixago.url = "github:jmgilman/nixago";
    nixago.inputs.nixpkgs.follows = "nixpkgs";

    nixago-exts.url = "github:nix-community/nixago-extensions";
    nixago-exts.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs = inputs @ { self, nixpkgs, nixago, nixago-exts, ... }:
    let
      # Helpers for producing system-specific outputs
      supportedSystems = [ "x86_64-linux" ];
      forEachSupportedSystem = f: nixpkgs.lib.genAttrs supportedSystems (system: f {
        inherit system;
        pkgs = import nixpkgs { inherit system; };
      });
    in
    rec
    {
      # Expose the configuration information.
      lib = {
        mkConfig =
          { system
          , pkgs
          , conform ? { }
          , contributorCovenant ? { }
          , developerCertificateOfOrigin ? { }
          , rust ? { }
          , ...
          }:
          let
            conformDefaults = { scopes = [ ]; };
            contributorCovenantDefaults = { enable = false; };
            developerCertificateOfOriginDefaults = { enable = false; };
            rustDefaults = { enable = false; };

            text-engine = import ./src/engines/text.nix {
              inherit pkgs;
              lib = pkgs.lib;
            };

            configs = import ./src/configs/default.nix {
              inherit system pkgs nixago nixago-exts;

              text-engine = text-engine { };

              contributorCovenant = contributorCovenantDefaults // contributorCovenant;
              developerCertificateOfOrigin = developerCertificateOfOriginDefaults // developerCertificateOfOrigin;
              conform = conformDefaults // conform;
              rust = rustDefaults // rust;
            };
          in
          {
            packages = [ pkgs.lefthook pkgs.treefmt ];

            shellHook = ''
              ${configs.shellHook}
              ${pkgs.lefthook}/bin/lefthook install
            '';
          };
      };

      # Set up the developer shell.
      devShells = forEachSupportedSystem ({ system, pkgs }:
        let
          config = lib.mkConfig {
            inherit system pkgs;
            contributorCovenant.enable = true;
            contributorCovenant.contact = "contact@mfgames.com";
            developerCertificateOfOrigin.enable = true;
          };
        in
        {
          # Shell
          default = pkgs.mkShell {
            packages = [ ] ++ config.packages;
            shellHook = config.shellHook;
          };
        });

      # Formatting for the Nix files
      formatter = forEachSupportedSystem ({ pkgs, ... }: pkgs.nixpkgs-fmt);
    };
}