mfgames-project-setup-flake/flake.nix

{
  description = "Common setup for many projects that use a variety of languages.";

  inputs = {
    nixpkgs.url = "https://flakehub.com/f/NixOS/nixpkgs/*.tar.gz";

    nixago.url = "github:jmgilman/nixago";
    nixago.inputs.nixpkgs.follows = "nixpkgs";

    nixago-exts.url = "github:nix-community/nixago-extensions";
    nixago-exts.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs = inputs @ { self, nixpkgs, nixago, nixago-exts, ... }:
    let
      # Helpers for producing system-specific outputs
      supportedSystems = [ "x86_64-linux" ];
      forEachSupportedSystem = f: nixpkgs.lib.genAttrs supportedSystems (system: f {
        inherit system;
        pkgs = import nixpkgs { inherit system; };
      });
    in
    rec
    {
      # Expose the configuration information.
      lib = {
        mkConfig =
          { system
          , pkgs
          , conform ? { }
          , rust ? { }
          , ...
          }:
          let
            rustDefaults = { enable = false; };
            conformDefaults = { scopes = [ ]; };
            configs = import ./src/configs/default.nix {
              inherit system pkgs nixago nixago-exts;
              conform = conformDefaults // conform;
              rust = rustDefaults // rust;
            };
          in
          {
            packages = [ pkgs.lefthook ];

            shellHook = ''
              ${configs.shellHook}
              ${pkgs.lefthook}/bin/lefthook install

              alias lefthook="${pkgs.lefthook}/bin/lefthook"
            '';
          };
      };

      # Set up the developer shell.
      devShells = forEachSupportedSystem ({ system, pkgs }:
        let
          config = lib.mkConfig {
            inherit system pkgs;
            #rust.enable = false;
          };
        in
        {
          # Shell
          default = pkgs.mkShell {
            packages = [ ] ++ config.packages;
            shellHook = config.shellHook;
          };
        });

      # Formatting for the Nix files
      formatter = forEachSupportedSystem ({ pkgs, ... }: pkgs.nixpkgs-fmt);
    };
}